Just read a quick breeze through of this thread and I think you may be overcomplicating this.

Scripting acts in an "in order" basis unless it is told to do something else.
To skip around you can open multiple threads.

For a simpler solution to this problem - why not open only 1 thread that has you complete OBJ1 (walk to the trigger without being seen or killing enemy or whatever...THEN in that same thread (after you reach your goal) open the thread for OBJ2 - or complete it in the same thread?

I believe that you could just move the operator "thread obj2();" to before the operator "obj1 delete();" so it starts the next thread before killing the current thread. Maybe add "wait 0.5;" after executing the obj2 thread to allow the code to execute

I haven't played with coding for a LOOOONG time so this is probably pretty rusty but i believe it should work



edited on Jan. 28, 2016 07:35 am by StrYdeR

You would still have the problem that you can kill the other guys

Ow wow , im really stupid.

#include maps\_utility;

#include maps\_anim;

#using_animtree("generic_human");

main()
{
	maps\_load::main();
	setExpFog(0.0001, 0.55, 0.6, 0.55, 0);

	ambientPlay("ambient_france");

	game["allies"] = "american";
	game["axis"] = "german";
	game["attackers"] = "allies";
	game["defenders"] = "axis";
	game["american_soldiertype"] = "normandy";
	game["german_soldiertype"] = "normandy";

	setCvar("r_glowbloomintensity0", ".25");
	setCvar("r_glowbloomintensity1", ".25");
	setcvar("r_glowskybleedintensity0", ".3");

	level.allies_accuracy = 10;
	level.axis_accuracy = 100;
	thread setupplayer();
	thread enemy();
	thread obj1();
}

setupplayer()
{
	level.player takeallweapons();
	level.player giveWeapon("mp40");
	level.player giveWeapon("luger");
	level.player switchToWeapon("mp40");
	level.player setViewmodel("xmodel/viewmodel_hands_german");
}

enemy()
{
	guys = getentarray("guy", "targetname");
	for (i = 0; i < guys.size; i++)
		guys[i] thread mission_failure();
}

obj1()
{
	obj1 = getent("obj1", "targetname");
	objective_add(1, "active", &"TESTING_OBJECTIVE_1", getent("obj1marker", "targetname").origin);
	objective_current(1);

	obj1 waittill("trigger");

	objective_state(1, "done");
	obj1 delete();

	thread obj2();
}


obj2()
{
	level.ending = 1;

	obj2 = getent("obj2", "targetname");
	objective_add(2, "active", &"TESTING_OBJECTIVE_2", getent("obj2", "targetname").origin);
	objective_current(2);

	obj2 waittill("death");
	objective_state(2, "done");
}

mission_failure()
{
	self waittill("death");
	if (!isdefined(level.ending))
	{
		setCvar("ui_deadquote", &"TESTING_MISSION_FAILURE_ALERTED_ENEMY");
		maps\_utility::missionFailedWrapper();
	}
}

Your first part was almost correct, but it should be this

		guys[i] thread mission_failure();

and the level.ending is now in the correct place

Ni3ls!!!! You're amazing!! Thank you so much for all of your help!! Seriously! It works perfectly! Now with this final touch my SP map will be finished! I'll post shortly with the final product of my map. Thanks again!! And thank you Stryder for your input too!